home *** CD-ROM | disk | FTP | other *** search
/ What PC? 2000 May / What PC May 2000 / wpcmay00.iso / SOFTWARE / UTILITY / vvho52uk / VIAVOICE.Z / numbers.bnf < prev    next >
Text File  |  1998-07-09  |  3KB  |  104 lines
  1. ;; ========= numbers <0.xxx - 999.999.999.xxx> ==========
  2.  
  3. <numbers> = <num> <digit-string>? .
  4.  
  5. <num> =   <zero> |
  6.           <tens-hundred> |
  7.           <seven-to-nine-digit-number> .
  8.  
  9. <two-digit-number> =   <non-zero-digit> |
  10.                        <teens> |
  11.                        <ten>  |
  12.                        <tens> <non-zero-digit>? .
  13.  
  14. <hundred-bit> =   <non-zero-digit> <hundred> |
  15.                   <one> <hundred> .
  16.  
  17. <other-two-digits> = <conj>? <two-digit-number> .
  18.  
  19. <tens-hundred> =   <teens-hundred> |
  20.                    <tens> <non-zero-digit> <hundred> <other-two-digits>? .
  21.  
  22. <teens-hundred> = <teens> <hundred> <other-two-digits>? .
  23.  
  24. <three-digit-number> =   <two-digit-number> |
  25.                          <hundred-bit> <other-two-digits>? .
  26.  
  27. <four-to-six-digit-number> =   <three-digit-number> <thousand>? |
  28.                                <three-digit-number> <thousand> <three-digit-number> |
  29.                                <three-digit-number> <thousand> <other-two-digits> .
  30.  
  31. <seven-to-nine-digit-number> =   <four-to-six-digit-number> |
  32.                                  <three-digit-number> <million> |
  33.                                  <three-digit-number> <million> <four-to-six-digit-number> |
  34.                                  <three-digit-number> <million> <other-two-digits> .
  35.  
  36. <digit-string> =   <point> <zero> |
  37.                    <point> <digit-bit-with-oh> |
  38.                    <point> <digit-bit-with-zero> .
  39.  
  40. <digit-bit-with-oh> =   <digit-with-oh>+ <non-zero-digit>  |
  41.                         <non-zero-digit> .
  42.  
  43. <digit-bit-with-zero> =   <digit-with-zero>+ <non-zero-digit> |
  44.                           <non-zero-digit> .
  45.  
  46. <one> =   a:"numbers_1" |
  47.           one:"numbers_1" .
  48.  
  49. <zero> =   zero:"numbers_0" |
  50.            oh:"numbers_0" |
  51.            nought:"numbers_0" .
  52.  
  53. <conj> = and:"numbers_?" .
  54.  
  55. <point> = point:"numbers_." .
  56.  
  57. <non-zero-digit> =   one:"numbers_1" |
  58.                      two:"numbers_2" |
  59.                      three:"numbers_3" |
  60.                      four:"numbers_4" |
  61.                      five:"numbers_5" |
  62.                      six:"numbers_6" |
  63.                      seven:"numbers_7" |
  64.                      eight:"numbers_8" |
  65.                      nine:"numbers_9" .
  66.  
  67.  
  68. <digit-with-oh> =   oh:"numbers_0" |
  69.                     <non-zero-digit> .
  70.  
  71. <digit-with-zero> =   zero:"numbers_0" |
  72.                       <non-zero-digit> .
  73.  
  74. <teens> =   eleven:"numbers_11" |
  75.             twelve:"numbers_12" |
  76.             thirteen:"numbers_13" |
  77.             fourteen:"numbers_14" |
  78.             fifteen:"numbers_15" |
  79.             sixteen:"numbers_16" |
  80.             seventeen:"numbers_17" |
  81.             eighteen:"numbers_18" |
  82.             nineteen:"numbers_19" .
  83.  
  84. <ten> = ten:"numbers_10" .
  85.  
  86. <tens> =   twenty:"numbers_20" |
  87.            thirty:"numbers_30" |
  88.            forty:"numbers_40" |
  89.            fifty:"numbers_50" |
  90.            sixty:"numbers_60" |
  91.            seventy:"numbers_70" |
  92.            eighty:"numbers_80" |
  93.            ninety:"numbers_90" .
  94.  
  95. <hundred> = hundred:"numbers_x100" .
  96.  
  97. <thousand> = thousand:"numbers_x1000&_)" .
  98.  
  99. <million> = million:"numbers_x1000000&_)" .
  100.  
  101. //NMC:VISIBLE
  102. ;; the above command is for the nav-macro-editor
  103.  
  104.